Check if computer is locked using WSH

Option Explicit
Dim strComputer
Dim objWMIService
Dim propValue
Dim objItem
Dim SWBemlocator
Dim UserName
Dim Password
Dim colItems
Dim strQuery
Dim strAssocQuery
Dim colLogon
Dim logon
Dim colUsers
Dim User

strComputer = "paj"
UserName = ""
Password = ""
strQuery="Select * from Win32_Process WHERE Name='explorer.exe'"
Set SWBemlocator = CreateObject("WbemScripting.SWbemLocator")

On Error Resume Next
Set objWMIService = SWBemlocator.ConnectServer(strComputer,_
"root\CIMV2",UserName,Password)
Set colItems = objWMIService.ExecQuery(strQuery)
If IsEmpty(colItems) Then
    WScript.Echo "Failed to connect or execute query"
    WScript.Echo "Error#" & Err.Number & " " & Err.Description
    WScript.Quit
Else
    On Error GoTo 0
    For Each objItem in colItems
        'WScript.Echo "Handle: " & objItem.Handle
        strAssocQuery="ASSOCIATORS OF {Win32_Process.Handle='" & _
         objItem.Handle & "'} WHERE ResultClass=Win32_LogonSession"
        Set colLogon=objWMIService.ExecQuery(strAssocQuery,,48)
        For Each logon In colLogon
            'WScript.Echo logon.LogonID
            Set colUsers=objWMIService.ExecQuery(_
            "ASSOCIATORS OF {Win32_LogonSession.LogonID='" &_
             logon.LogonID & "'} WHERE ResultClass=Win32_UserAccount")
            For Each User In colUsers
                WScript.Echo "Current user logged on to " &_
                 UCase(strComputer) & " is probably " &_
                  user.domain & "\" & User.Name
            Next
        Next

    Next
End If